+{

+  "cmd": "./compile",

+  "sh": "true",

+  "cwd": "{PROJECT_PATH}"

+}

+/screenshot

+/old

+/readme

+/examples

+*.zip

+*.8*

+*.exe

+*.bin

+*.png

+*.gif

+[submodule "z80float"]

+	path = z80float

+	url = https://github.com/Zeda/z80float.git

+# Readme

+For a tutorial/documentation on the commands open [/readme/commands.html](/docs/readme.md)

+

+# Building

+

+Binaries are available in the `/bin` folder, but for developers, building from source might be useful.

+

+This project uses [`spasm-ng`](https://github.com/alberthdev/spasm-ng) to compile, and I use Linux. On windows you can either use the [`linux subsytem`](https://www.windowscentral.com/install-windows-subsystem-linux-windows-10)(only on windows 10) and install spasm from there or you can download the [`spasm-ng`](https://github.com/alberthdev/spasm-ng/releases) for Windows release.

+

+***NOTE:** at the time of this writing, it appears that spasm-ng has a bug that doesn't parse the name field correctly.

+Please use this version for now: https://github.com/alberthdev/spasm-ng/tree/feature/app-name-var-size.*

+

+## Linux:

+From the command line, run `./compile`

+

+## Windows:

+Download Windows [`spasm-ng`](https://github.com/alberthdev/spasm-ng/releases) release, rename it to `spasm.exe` and place it in the project directory. From command prompt or powershell cd to the project directory and run `compile.bat`.

+

+This generates the jump table and compiles the app and Grammer package.

+Hey! Look in the "readme" folder, and open "readme.html" in your browser :)

+The easiest way to submit bug reports is through GitHub:

+    https://github.com/Zeda/Grammer2/issues

+

+That's also where the most up-to-date versions will be :)

+#!/bin/bash

+

+cd src

+

+echo -e "\e[1m\e[37mGenerating grammer2.5.inc\e[0m"

+python jt.py jmptable.z80 grammer2.5.inc

+cp grammer2.5.inc ../docs/grammer2.5.inc

+

+#echo -e "\e[1m\e[37mAssembling Default Package\e[0m"

+#spasm grampkg.z80 ../bin/grampkg.8xv

+

+echo -e "\e[1m\e[37mAssembling App\e[0m"

+spasm grammer.z80 ../bin/grammer.8xk -I ../z80float/single

+

+# Check for an experimental package

+if [ ! -f "experimental/experimental.z80" ];then

+  echo -e "\e[1m\e[37mAssembling Experimental Package\e[0m"

+  spasm experimental/experimental.z80 ../bin/EXPRMNTL.8xv -I single

+fi

+@echo off

+if exist spasm.exe (

+  echo "Starting Compile..."

+) else (

+  echo "Opening readme..."

+  start "" https://github.com/Zeda/Grammer2/blob/master/Readme.md

+  exit

+)

+

+cd src

+

+echo "Generating grammer2.5.inc"

+python jt.py jmptable.z80 grammer2.5.inc

+copy /Y grammer2.5.inc ..\docs\grammer2.5.inc

+

+echo "Assembling Default Package"

+..\spasm.exe grampkg.z80 ..\bin\grampkg.8xv

+

+echo "Assembling App"

+..\spasm.exe grammer.z80 ..\bin\grammer.8xk -I ..\z80float\single

+

+rem Check for an experimental package

+if exist experimental\experimental.z80 (

+  echo "Assembling Experimental Package"

+  ..\spasm.exe experimental\experimental.z80 ..\bin\EXPRMNTL.8xv -I single

+)

+

+cd..

+.org $4000

+#define scrap 8000h

+#include "gfx/bigtile.z80"

+#include "isort.z80"

+;#include "compile.z80"

+

+drawrect:

+#include "gfx/drawrect.z80"

+#include "math/rand_single.z80"

+#include "math/atanbin.z80"

+#include "gfx/circle.z80"

+#include "gfx/filledcircle.z80"

+#include "gfx/tilemap.z80"

+

+p1_GraphToLCD:

+#include "gfx/gbufToLCD_speed.z80"

+

+call_ix_01:

+  jp (ix)

+

+pixelOn_pattern:

+  call getpixelloc

+  ret nc

+  or (hl)

+  ld (hl),a

+  ret

+pixelOff_pattern:

+  call getpixelloc

+  ret nc

+  cpl

+  and (hl)

+  ld (hl),a

+  ret

+pixelToggle_pattern:

+  call getpixelloc

+  ret nc

+  xor (hl)

+  ld (hl),a

+  ret

+

+#include "absSingle.z80"

+#include "negSingle.z80"

+#include "cmpSingle.z80"

+

+#include "randSingle.z80"

+

+#include "acosSingle.z80"

+#include "asinSingle.z80"

+#include "atanSingle.z80"

+#include "acoshSingle.z80"

+#include "asinhSingle.z80"

+#include "atanhSingle.z80"

+#include "coshSingle.z80"

+#include "sinhSingle.z80"

+#include "tanhSingle.z80"

+#include "tanSingle.z80"

+

+

+#include "powSingle.z80"

+#include "pow10Single.z80"

+#include "logSingle.z80"

+#include "lgSingle.z80"

+#include "log10Single.z80"

+

+#include "single2str.z80"

+#include "str2single.z80"

+#include "singleTo_int16.z80"

+

+

+#ifdef INCLUDE_GRAMPKG

+grampkg_start:

+#define EXCLUDE_GRAMPKG_INC

+#include "grampkg.z80"

+grampkg_end:

+#endif

+

+menu_code_start:

+#include "cmd/menu.z80"

+#include "cmd/searchstring.z80"

+

+#include "io/getKeyChar.z80"

+#include "io/getKeyTok.z80"

+#include "io/input.z80"

+#include "io/menu.z80"

+#include "io/sound.z80"

+

+#include "cmd/prime.z80"

+#include "cmd/param.z80"

+#include "cmd/solve.z80"

+#include "subroutines/searchline.z80"

+#include "subroutines/zlz_decomp.z80"

+#include "subroutines/zlz_comp.z80"

+#include "subroutines/heapsort.z80"

+#include "subroutines/zcomp.z80"

+

+p1_PutTokenText:

+  ld bc,PutTokenText

+  ld (prev_page_call_address),bc

+  jp prev_page_call

+

+p1_ParseFullArg:

+  ld hl,ParseFullArg

+  ld (prev_page_call_address),hl

+  jp prev_page_call

+

+p1_ParseNextFullArg:

+  ld hl,ParseNextFullArg

+  ld (prev_page_call_address),hl

+  jp prev_page_call

+

+p1_ParserNext:

+  ld hl,ParserNext

+  ld (prev_page_call_address),hl

+  jp prev_page_call

+

+p1_err_fatal:

+p1_err_syntax:

+  push hl

+  ld hl,err_fatal

+  jr jp_prev_page_call

+

+p1_ErrBadToken:

+  push hl

+  ld hl,ErrBadToken

+  jr jp_prev_page_call

+

+p1_ErrStackOverflow_push:

+  push hl

+  ld hl,ErrStackOverflow_push

+  jr jp_prev_page_call

+

+p1_ErrStackOverflow_pop:

+  push hl

+  ld hl,ErrStackOverflow_pop

+  jr jp_prev_page_call

+

+p1_ErrMem:

+  push hl

+  ld hl,ErrMem

+  jr jp_prev_page_call

+

+p1_VarP:

+  push hl

+  ld hl,VarP

+  jr jp_prev_page_call

+

+p1_parse_by_ptr_to_ptr:

+  push hl

+  ld hl,parse_by_ptr_to_ptr

+  jr jp_prev_page_call

+

+p1_GetGrammerStr:

+  push hl

+  ld hl,GetGrammerStr

+  jr jp_prev_page_call

+

+p1_GetVarInfo2:

+  push hl

+  ld hl,GetVarInfo2

+  jr jp_prev_page_call

+

+p1_GetVarInfo:

+  push hl

+  ld hl,GetVarInfo

+  jr jp_prev_page_call

+

+p1_EndOfLine:

+  push hl

+  ld hl,EndOfLine

+  jr jp_prev_page_call

+

+p1_getKeyDebounce:

+  push hl

+  ld hl,getKeyDebounce

+jp_prev_page_call:

+  ld (prev_page_call_address),hl

+  pop hl

+  jp prev_page_call

+

+verify_package:

+;A:HL points to the data

+;BC is the size of the data

+;Returns carry flag reset if good, carry set if bad

+

+;Need to read 4-byte magic number

+;Need to read the valid version number and size of table

+;Verify that the package has at least 8 bytes

+  inc b

+  dec b

+  jr nz,+_

+  ld b,a

+  ld a,c

+  cp 8

+  ld a,b

+  ret c

+_:

+;If magic number doesn't match, then we quit

+;If it does match, then we'll assume it is formatted

+;correctly. No need to save BC (or DE for that matter)

+;Just need A:HL

+

+  ld bc,6

+  ld de,cmdShadow

+  call ReadArc

+

+;magic number

+  ex de,hl

+  or a

+  ld hl,(cmdShadow)

+  .db 1 ;start of ld bc,**

+  .db "Gr"

+  sbc hl,bc

+  scf

+  ret nz

+  or a

+  ld hl,(cmdShadow+2)

+  .db 1 ;start of ld bc,**

+  .db "am"

+  sbc hl,bc

+  scf

+  ret nz

+;pkg version

+  ld hl,(cmdShadow+4)

+  ld bc,MODULE_VERSION-1

+  sbc hl,bc

+  ret

+

+FS_find_new:

+  ld hl,(FS_begin)

+  jr FS_find_new_start

+

+FS_find_new_loop:

+  ld b,a

+  ld c,a

+  cpir

+  ld c,(hl)

+  inc hl

+  ld b,(hl)

+  inc hl

+  add hl,bc

+FS_find_new_start:

+  xor a

+  cp (hl)

+  jr nz,FS_find_new_loop

+  ret

+

+FS_createvar_max_01:

+;Input:

+;   HL points to the name

+;   BC is the size of the name (sans null-byte)

+;Output:

+;   HL points to the data

+;   BC is the size

+;   DE points to the name

+;

+  push hl

+  push bc

+

+  call FS_find_new

+  ;HL points to where to write it

+  ;Make sure that HL+BC+2 - (FS_end) < 0

+  push hl

+  add hl,bc

+  inc hl

+  inc hl

+  ld de,(FS_end)

+  ; or a

+  sbc hl,de

+  jp nc,p1_ErrMem

+

+

+  ;Now -HL-1 is going to be the size of the var!

+  ld a,h

+  cpl

+  ld h,a

+  ld a,l

+  cpl

+  ld l,a

+

+

+  pop de

+  pop bc

+  ex (sp),hl

+  ;DE is where to write

+  ;HL is the string

+  ;BC is the size

+  push de

+  ldir

+  ex de,hl

+  pop de

+  pop bc

+  ld (hl),0

+  inc hl

+  ld (hl),c

+  inc hl

+  ld (hl),b

+  inc hl

+  ret

+

+FS_delvar_01:

+  call FS_findvar_01

+  add hl,bc

+  ; or a

+  sbc hl,de

+  ; Need to delete HL bytes at DE

+

+  ;Need to set up the buf_end and buf_top, first

+  push hl

+  ld hl,(FS_end)

+  ld (buf_top),hl

+  call FS_find_new

+  ld (buf_end),hl

+  pop bc

+  ex de,hl

+  call delmem

+  ret nc

+  jp p1_ErrMem

+

+FS_resize_01:

+;HL points to the data

+;BC is the new size

+  ;Need to set up the buf_end and buf_top, though

+  ex de,hl

+  push bc

+  ld hl,(FS_end)

+  ld (buf_top),hl

+  call FS_find_new

+  ld (buf_end),hl

+  pop bc

+  ex de,hl

+

+  dec hl

+  ld d,(hl)

+  ld (hl),b

+  dec hl

+  ld e,(hl)

+  ld (hl),c

+  inc hl

+  inc hl

+  push hl

+  push bc

+

+  add hl,bc

+  ;HL points to the end of the data

+  ;need to deallocate DE-BC bytes (if negative, then bytes are allocated!)

+  ex de,hl

+;  or a

+  sbc hl,bc

+  ex de,hl

+

+  ld b,d

+  ld c,e

+  call delmem

+  pop bc

+  pop hl

+  ret nc

+  jp p1_ErrMem

+

+#include "subroutines/insertdelmem.z80"

+

+

+

+FS_findvar_01:

+;Input:

+;   HL points to the name of the var to find

+;Output:

+;   Carry flag is set if found

+;     HL points to the var's data

+;     DE pointing to the var name

+;     BC is the size

+;

+  ex de,hl

+  ld hl,(FS_begin)

+  jr FS_findvar_begin

+

+FS_findvar_loop:

+

+  ;Then assume the file is not malformed

+  push hl

+  push de

+  call cpstr

+  pop de

+  jr z,FS_file_found

+  pop af    ;Don't need to save the pointer to the file name

+

+

+  ;File not found, so seek the end of the name

+  xor a

+  ld b,a

+  ld c,a

+  cpir

+

+  ;Now HL points to the size bytes

+  ;need to skip the data

+  ld c,(hl)

+  inc hl

+  ld b,(hl)

+  inc hl

+  add hl,bc

+

+FS_findvar_begin:

+  ;Check if there are any more files

+  ld a,(hl)

+  or a

+  ret z

+

+  ;Check if HL is past FS_end

+  ld bc,FS_end

+  or a

+  sbc hl,bc

+  add hl,bc

+  ret z

+  jr c,FS_findvar_loop

+  scf

+  ret

+

+FS_file_found:

+  inc hl

+  ld c,(hl)

+  inc hl

+  ld b,(hl)

+  inc hl

+  pop de

+  ret

+

+_:

+  inc de

+  inc hl

+cpstr:

+;Compare two strings at HL and DE

+;returns z if they are equal

+;returns c is DE points to the smaller string

+;returns nc if DE is the bigger (or equal) string.

+  ld a,(de)

+  cp (hl)

+  ret nz

+  or a

+  jr nz,-_

+  ret

+

+LblToken_01:

+  call p1_ParseFullArg

+  push bc

+  ld h,b

+  ld l,c

+  call p1_GetGrammerStr

+  pop hl

+  push bc

+

+  ld de,OP2

+  ld a,3Fh

+  ld (de),a

+  inc de

+  ld a,3Ah

+  ld (de),a

+  inc de

+  ldir

+  ld a,3Fh

+  ld (de),a

+  ld hl,(parsePtr)

+  ld a,(hl)

+  cp 2Bh

+  jr nz,+_

+  inc hl

+  ld (parsePtr),hl

+  call p1_GetVarInfo2

+  jr nc,LblToken_ptrdone

+_:

+  ld hl,(progEnd)

+  ld de,(progStart)

+  or a

+  sbc hl,de

+  ld b,h

+  ld c,l

+  ex de,hl

+LblToken_ptrdone:

+  ld de,OP2

+  pop ix

+  ld de,3

+  add ix,de

+  ld de,OP2

+  call searchstring_routine

+  jp nc,p1_ErrBadToken

+  inc hl

+  call p1_EndOfLine

+  ld b,h

+  ld c,l

+  ret

+

+#include "tokenhook.z80"

+#include "modemenu.z80"

+

+.echo "Page 1: ",$8000-$," bytes remaining"

+My near-term plan is to do some simple optimizations when copying programs to RAM. My first idea is to replace all Lbl commands with their actual pointer value since labels are static. This will also allow me to remove labels/comments from executing code making it smaller and slightly faster. Note that I won't be doing this to code already in RAM :(

+SetUpData:

+  bcall(_RunIndicOff)

+  call setup_readarc

+

+;initialize the float rand routine

+  ld hl,randinit

+  ld (next_page_call_address),hl

+  call next_page_call

+

+  ld hl,floatstack_bottom

+  ld (floatstack_ptr),hl

+  ld hl,seed2+1

+  set 6,(hl)

+  dec l

+  dec l

+  ld a,r \ xor (hl) \ ld (hl),a

+  ld hl,plotSScreen

+  ld (BufPtr),hl

+  ld (GrayBufPtr),hl

+  ld hl,PBuf

+  ld (PBufPtr),hl

+  ld hl,766

+  ld (PBuf),hl

+  ld a,3

+  ld (OutputLogic),a

+  ld (TextPauseTime),a

+  ld hl,FontSet

+  ld (FontPointer),hl

+  xor a

+  ld (font_ptr_page),a

+  ld (module_count),a

+  ld h,a

+  ld l,a

+  ld (flags+33),a

+  ld (flags+34),hl

+  ld (IntLoc),hl

+  ld (PBufType),hl

+  ld (textmode),a

+  ld hl,$0155

+  ld (GrayMask),hl

+

+  ld hl,saveSScreen+256

+  ld (stack_base),hl

+  ld (stack_ptr),hl

+  inc h

+  inc h

+  ld (stack_top),hl

+

+  ld hl,textShadow

+  ld (input_base),hl

+  ld hl,128

+  ld (input_size),hl

+

+

+#ifndef INCLUDE_GRAMPKG

+;Verify the grammer package

+  ld hl,verify_package

+  ld (next_page_call_address),hl

+  ld hl,s_grampkg

+  rst rMov9ToOP1

+  bcall(_ChkFindSym)

+  ld a,b

+  ld b,0

+  call nc,next_page_call

+  jr nc,+_

+  set nogrampkg,(iy+InternalFlags)

+_:

+#endif

+

+  pop hl

+  ld (SPSave),sp

+  jp (hl)

+setupRAMdata:

+;not speed critical

+  ld de,8100h

+  ld hl,RAMCodeStart

+  ld bc,RAMCodeEnd-RAMCodeStart

+  ldir

+  ret

+FireCycle:

+  dec a \ jr nz,FireCycle2

+

+  ld a,e

+  ld de,12

+  ex de,hl

+  add hl,de

+  ld bc,2F4h

+  or a

+  jr z,BlackFireLoop

+FireLoop:

+  call Random

+  cpl

+  and (hl)

+  ld (de),a

+  inc de

+  cpi

+  jp pe,FireLoop

+  ret

+BlackFireLoop:

+  call Random

+  or (hl)

+  ld (de),a

+  inc de

+  cpi

+  jp pe,BlackFireLoop

+  ret

+FireCycle2:

+  dec a

+  ret nz

+  push de

+  push hl

+  call ParseNextFullArg

+;Y,X

+  ld h,b

+  ld l,c

+  add hl,hl

+  add hl,bc

+  add hl,hl

+  add hl,hl

+  pop bc

+  add hl,bc

+  push hl

+  call ParseNextFullArg

+  pop hl

+  add hl,bc

+  push hl

+;HL is now the start location

+;Width,Height:

+  call ParseNextFullArg

+  ld a,c

+  push af

+  call ParseNextFullArg

+  pop af

+  ld b,a

+  pop hl

+  pop de

+;b is width

+;c is height

+;e is the particle type

+  ld d,c

+  ld a,12

+  sub b

+  ld c,a

+  ld a,e \ or a

+  ld a,d

+  ld de,12

+  ex de,hl

+  add hl,de

+;a=height

+;b is width

+;c=12-b

+  jr z,BlackFireLoop2

+FireLoop2:

+  push af

+  push bc

+  call Random

+  cpl

+  and (hl)

+  ld (de),a

+  inc de

+  inc hl

+  djnz FireLoop2+2

+  add hl,bc

+  ex de,hl

+  add hl,bc

+  ex de,hl

+  pop bc

+  pop af

+  dec a

+  jr nz,FireLoop2

+  ret

+BlackFireLoop2:

+  push af

+  push bc

+  call Random

+  or (hl)

+  ld (de),a

+  inc de

+  inc hl

+  djnz BlackFireLoop2+2

+  add hl,bc

+  ex de,hl

+  add hl,bc

+  ex de,hl

+  pop bc

+  pop af

+  dec a

+  jr nz,BlackFireLoop2

+  ret

+Random:

+;preserve HL,DE,BC

+  push hl

+  push de

+  push bc

+  call prng16

+  ld a,h

+  and l

+  and b

+  pop bc

+  pop de

+  pop hl

+  ret

+;From Axe

+p_Input:

+ res 6,(iy+$1C)

+ set 7,(iy+$09)

+ xor a

+ ld (ioPrompt),a

+ B_CALL(_GetStringInput)

+ B_CALL(_ZeroOP1)

+ ld a,$2D

+ ld (OP1+1),a

+ rst rFindSym

+ inc de

+ inc de

+ ex de,hl

+ ret

+__InputEnd:

+LineToken:

+

+  call ParseNextFullArg_Inc

+  push bc

+  call ParseNextFullArg

+  pop de

+  ld b,e

+  push bc

+  call ParseNextFullArg

+  push bc

+  call ParseNextFullArg

+  pop de

+  ld b,e

+  push bc

+  cp $2b

+  ld c,1

+  call z,ParseNextFullArg

+  cp $2b

+  ld a,c

+  push af

+  call ParseNextFullArg_BC

+  cp $2b

+  jr nz,L5971

+  inc hl

+  ld a,(hl)

+  cp $ae

+  jr nz,+_

+  call ParseNextFullArg_Inc

+  push bc

+  jr L596f

+_:

+  ld hl,$80ff

+  push hl

+_:

+  push hl

+  call ParseNextFullArg

+  pop hl

+  ld (hl),c

+  dec l

+  jp p,+_

+  cp $2b

+  jr z,-_

+_:

+  ld (hl),$ff

+L596f:

+  pop ix

+L5971:

+  pop af

+  pop de

+  pop hl

+  ld c,a

+  ld a,d

+  sub h

+  ld d,a

+  ld a,e

+  sub l

+  ld e,a

+  ld a,c

+DrawLine:

+  di

+  res FactorialFlag,(iy+InternalFlag)

+  res Mod2nd,(iy+InternalFlag)

+  bit 2,a

+  jr z,+_

+  set FactorialFlag,(iy+InternalFlag)

+_:

+  bit 3,a

+  jr z,+_

+  set Mod2nd,(iy+InternalFlag)

+_:

+  and $f3

+  ld bc,$A62F

+  dec a

+  jr nz,+_

+  ld bc,$00B6

+_:

+  dec a

+  jr nz,+_

+  ld bc,$00AE

+_:

+  ld ($8101),bc

+  ld a,$ff

+  ld ($811a),a

+  res grayMode,(iy+InternalFlag)

+  ld a,(ix)

+  bit Mod2nd,(iy+InternalFlag)

+  jr nz,+_

+  inc a

+_:

+  ld ($8109),a

+  or a

+  call z,L7158

+  ld c,0

+  ld a,d

+  bit 7,a

+  jr z,+_

+  neg

+  set 6,c

+  ld d,a

+_:

+  ld a,e

+  bit 7,a

+  jr z,+_

+  neg

+  set 7,c

+  ld e,a

+_:

+  ld b,a

+  ex af,af'

+  ld a,c

+  exx

+  rla

+  ld de,12

+  ld bc,1

+  jr nc,+_

+  ld de,-12

+_:

+  rla

+  jr nc,+_

+  dec bc

+  dec bc

+_:

+  exx

+  ld a,h

+  push hl

+  push bc

+  ld h,00

+  ld b,h

+  ld c,l

+  add hl,hl

+  add hl,bc

+  add hl,hl

+  add hl,hl

+  ld c,a

+  sra c

+  sra c

+  sra c

+  jp p,+_

+  dec b

+_:

+  add hl,bc

+  ld bc,(gbuf_temp)

+  add hl,bc

+  and $07

+  ld b,a

+  ld a,$80

+  jr z,+_

+  rrca

+  djnz $-1

+_:

+  push hl

+  exx

+  pop hl

+  exx

+  ex af,af'

+  pop bc

+  pop hl

+  sla e

+  jr nz,L5a2b

+  ld b,d

+_:

+  call L5a6f

+  call L5a5d

+  djnz -_

+  ret

+

+L5a2b:

+ sla d

+L5a2d:

+ call L5a6f

+ sub d

+ jr c,L5a39

+ call L5a4b

+ djnz L5a2d

+ ret

+

+L5a39:

+ call L5a5d

+ add a,e

+ jr c,L5a45

+ call L5a6f

+ jp L5a39

+L5a45:

+ call L5a4b

+ djnz L5a2d

+ ret

+

+L5a4b:

+ bit Mod2nd,(iy+InternalFlag)

+ call nz,$8106

+ exx

+ add hl,de

+ exx

+ inc l

+ bit 7,c

+ ret z

+ dec l

+ dec l

+ ret

+

+L5a5d:

+ ex af,af'

+ rrca

+ inc h

+ bit 6,c

+ jr z,+_

+ dec h

+ dec h

+ rlca

+ rlca

+_:

+  jr nc,+_

+  exx

+  add hl,bc

+  exx

+_:

+  ex af,af'

+  ret

+

+L5a6f:

+  bit FactorialFlag,(iy+InternalFlag)

+  call nz,$8106

+  bit grayMode,(iy+InternalFlag)

+  ret nz

+  push af

+  ld a,l

+  cp $40

+  jr nc,+_

+  ld a,h

+  cp $60

+  jr nc,+_

+  ex af,af'

+  exx

+  call $8100

+  exx

+  ex af,af'

+_:

+  pop af

+  ret

+.echo "DrawLine : ",$-DrawLine

+LoadTSA:

+  di

+  push af

+  push bc

+  push de

+  push ix

+  ex (sp),hl

+  ld c,(hl) \ inc hl

+  ld b,(hl) \ inc hl

+  ld de,TSA

+  ;should I do a fastLDIR ?

+  ldir

+  pop hl

+  pop de

+  pop bc

+  pop af

+  ret

+menuMem = saveSScreen

+;Now define where vars are located, 17 bytes required in all.

+textbox_top     = menuMem

+textbox_left    = textbox_top+1    ;needs to follow textbox_top

+textbox_bottom  = menuMem+2

+textbox_width   = textbox_bottom

+textbox_right   = textbox_bottom+1 ;needs to follow textbox_bottom

+menucallptr     = menuMem+4

+menutop         = menuMem+6

+menucur         = menuMem+8

+menuselection   = menuMem+10

+menuheader_ptr  = menuMem+12

+menuheader_coord= menuMem+14

+menuheader_cur  = menuMem+16  ;1 byte

+menu_num_items  = menuMem+17  ;2 bytes

+menu_get        = menuMem+19

+menu_sel        = menuMem+21

+menu_temp       = menuMem+23

+menuopts        = menuMem+25

+menudefault     = TempWord1

+menutopinit     = TempWord4

+

+#define MENU_MAX_ELEMENTS ((menuMem+768-menuopts)>>1)

+

+;Menu:

+;Get the y coordinate

+  ld hl,(parsePtr)

+  ld a,(hl)

+  cp $AE

+  jp z,fancymenu

+  call p1_ParseFullArg

+  push bc

+

+;Get the x coordinate

+  call p1_ParseNextFullArg

+  pop hl

+  ld h,c

+

+;Save the coords

+  ld (textbox_top),hl

+

+; Get the width of the menu

+  call p1_ParseNextFullArg

+  ld (textbox_width),bc

+

+;Get the header

+  call p1_ParseNextFullArg

+  ld (menuheader_ptr),bc

+

+  ld hl,menuopts

+  ld bc,0

+menu_param_loop:

+  inc bc

+  ld a,b

+  cp MENU_MAX_ELEMENTS>>8

+  jr nz,+_

+  ld a,c

+  cp MENU_MAX_ELEMENTS&255

+  jp menu_err

+_:

+  push bc

+  push hl

+  ld hl,(parsePtr)

+  inc hl

+  ld a,(hl)

+  cp $AE

+  jr z,menu_select_default

+

+  call p1_ParseNextFullArg